@echo off
echo Setup wird gestartet...

REM Prüfen ob Python installiert ist
python --version
IF %ERRORLEVEL% NEQ 0 (
    echo Python ist nicht installiert!
    echo Bitte installieren Sie Python 3.10 oder neuer.
    pause
    exit
)

REM Virtuelle Umgebung erstellen
IF NOT EXIST myenv (
    echo Erstelle virtuelle Umgebung...
    python -m venv myenv
)

REM venv aktivieren
call myenv\Scripts\activate

REM pip aktualisieren
REM Aktualisiere pip...
python -m pip install --upgrade pip

REM RFEM-Version abfragen
set /p rfem_version=RFEM-Version eingeben (z.B. 6.12.0010):

REM Versionsnummer zerlegen
for /f "tokens=1-3 delims=." %%a in ("%rfem_version%") do (
    set major=%%a
    set minor=%%b
    set build=%%c
)

REM prüfen ob Eingabe korrekt ist
IF "%major%"=="" (
    echo Ungueltiges Format!
    pause
    exit
)
IF "%minor%"=="" (
    echo Ungueltiges Format!
    pause
    exit
)
IF "%build%"=="" (
    echo Ungueltiges Format!
    pause
    exit
)

REM Führende Nullen entfernen
set build_num=%build%
:strip
if not "%build_num%"=="" (
    if "%build_num:~0,1%"=="0" (
        set build_num=%build_num:~1%
        goto strip
    )
)

REM dlubal.api-Version zusammensetzen
set api_version=2.%minor%.%build_num%

echo Installiere dlubal.api Version %api_version% ...

REM Pakete installieren
echo Installiere benoetigte Pakete... (Dies kann einige Minuten dauern)
pip install numpy==2.2.6 pandas==2.2.3 streamlit==1.54.0 dlubal.api==%api_version% --prefer-binary --quiet

REM API-Key konfigurieren
echo.
echo Bitte geben Sie Ihren Dlubal API-Key ein:
set /p api_key=API-Key: 

REM config.ini Pfad setzen
set config_path=myenv\Lib\site-packages\dlubal\api\config.ini

REM config.ini erstellen
(
echo [api_keys]
echo api_key = %api_key%
echo default = %api_key%
) > "%config_path%"

echo API-Key wurde erfolgreich in myenv\Lib\site-packages\dlubal\api\config.ini gespeichert.

echo Setup erfolgreich abgeschlossen!
echo Sie koennen nun die Anwendung mit start_app.bat starten.
pause