701x
004975
2021-04-08

Вопрос

Как с помощью интерфейса COM изменить параметры расчета загружения?


Ответ:

Параметры расчета загружения нельзя задать сразу при его создании, а только потом, посредством интерфейса существующего загружения. Чтобы получить доступ к интерфейсу загружения, нужно сначала получить доступ к интерфейсам «IModel» и «ILoads»:


Sub test_analysis_parameters()

Dim iApp As RFEM5.Application
Set iApp = GetObject(, "RFEM5.Application")

iApp.LockLicense

Dim iMod As RFEM5.IModel3
Set iMod = iApp.GetActiveModel

On Error GoTo e

'   get interface of loads
Dim iLds As RFEM5.iLoads
Set iLds = iMod.GetLoads

'   get interface of load case
Dim iLc As RFEM5.ILoadCase
Set iLc = iLds.GetLoadCase(1, AtNo)

'   get analysis parameters
Dim param_analy As RFEM5.AnalysisParameters
param_analy = iLc.GetAnalysisParameters

'   change analysis parameters
param_analy.Method = Postcritical
param_analy.ModifyLoadingByFactor = True
param_analy.LoadingFactor = 1.5
'   ...

'   set new analysis parameters
iLds.PrepareModification
iLc.SetAnalysisParameters param_analy
iLds.FinishModification

e:

If Err.Number <> 0 Then MsgBox Err.description, vbCritical, Err.Source

iMod.GetApplication.UnlockLicense
Set iMod = Nothing

End Sub

Теперь используйте команду ILoads.GetLoadcase, чтобы получить доступ к интерфейсу для конкретного загружения. Данный интерфейс затем предоставляет и функции «GetAnalysisParameters» и «SetAnalysisparameters», которые можно использовать также для считывания и записи параметров.

Одинаковую процедуру можно применить и для сочетаний нагрузок.