704x
004975
8.4.2021

Dotaz

Jak mohu změnit parametry výpočtu zatěžovacího stavu pomocí rozhraní COM?


Odpověď:

Parametry výpočtu zatěžovacího stavu není možné zadat při jeho vytvoření, ale až následně přes rozhraní existujícího zatěžovacího stavu. Pro získání rozhraní zatěžovacího stavu je třeba nejdříve získat rozhraní 'IModel' a 'ILoads':


Sub test_analysis_parameters()

Dim iApp As RFEM5.Application
Set iApp = GetObject(, "RFEM5.Application")

iApp.LockLicense

Dim iMod As RFEM5.IModel3
Set iMod = iApp.GetActiveModel

On Error GoTo e

'   get interface of loads
Dim iLds As RFEM5.iLoads
Set iLds = iMod.GetLoads

'   get interface of load case
Dim iLc As RFEM5.ILoadCase
Set iLc = iLds.GetLoadCase(1, AtNo)

'   get analysis parameters
Dim param_analy As RFEM5.AnalysisParameters
param_analy = iLc.GetAnalysisParameters

'   change analysis parameters
param_analy.Method = Postcritical
param_analy.ModifyLoadingByFactor = True
param_analy.LoadingFactor = 1.5
'   ...

'   set new analysis parameters
iLds.PrepareModification
iLc.SetAnalysisParameters param_analy
iLds.FinishModification

e:

If Err.Number <> 0 Then MsgBox Err.description, vbCritical, Err.Source

iMod.GetApplication.UnlockLicense
Set iMod = Nothing

End Sub

Pomocí 'ILoads.GetLoadcase' lze získat rozhraní pro určitý zatěžovací stav. Toto rozhraní poskytuje funkce 'GetAnalysisParameters' a 'SetAnalysisparameters', pomocí nichž lze parametry číst a zapisovat.

Stejný postup lze použít i pro kombinace zatížení.