Selektion von Knoten entlang einer Linie mit Hilfe der COM-Schnittstelle

Fachbeitrag

Wenn man über die COM-Schnittstelle die Ergebnisse einer Fläche ausliest, so erhält man ein eindimensionales Feld mit allen Ergebnissen an den FE-Knoten oder Rasterpunkten. Um die Ergebnisse am Rand einer Fläche oder entlang einer Linie innerhalb der Flächen zu erhalten, müssen die Ergebnisse im Bereich der Linie herausgefiltert werden. Im Folgenden wird eine Funktion vorgestellt, welche diese Aufgabe übernehmen kann.

Theoretische Grundlagen zur Abstandsberechnung

Um die FE-Knoten zu finden, welche in der Nähe beziehungsweise auf der Linie liegen, muss der Abstand des Knotens zur Linie berechnet werden. Gegeben sind die Linie mit Anfangs- und Endpunkt (N0 und N1) und der Punkt P, dessen Abstand zur Linie ermittelt werden soll. Ein gängiger Weg für die Berechnung dieses Abstandes ist, dass eine Ebene aufgespannt wird, welche durch den Punkt P verläuft und senkrecht auf der Geraden steht. Dazu muss zunächst eine geeignete Geradengleichung aufgestellt werden. In diesem Fall bietet sich die Parameterform an, welche einen Richtungsvektor v beinhaltet. Dieser kann danach zum Aufstellen der Ebenengleichung verwendet werden.

$\mathrm{Gerade}\;\mathrm G:\;\overset\rightharpoonup{\mathrm X}\;=\;\overset\rightharpoonup{\mathrm A}\;+\;\mathrm s\;\cdot\;\overset\rightharpoonup{\mathrm v}\;(1)\\\mathrm{mit}\\\mathrm A\;=\;{\mathrm N}_0\\\mathrm v\;=\;{\mathrm N}_1\;-\;{\mathrm N}_0$

Für den Stützvektor A wird der Anfangspunkt (Ortsvektor) der Linie verwendet und für den Richtungsvektor v die Differenz der beiden Ortsvektoren. Als Ebenengleichung wird die Normalform aus dem bereits erwähnten Grund verwendet.

$\mathrm{Ebene}\;\mathrm E:\;0\;=\;(\overset\rightharpoonup{\mathrm X}\;-\;\overset\rightharpoonup{\mathrm P})\;\cdot\;\overset\rightharpoonup{\mathrm n}\;(2)\\\mathrm{mit}\\\overset\rightharpoonup{\mathrm n}\;=\;\overset\rightharpoonup{\mathrm v}\\\overset\rightharpoonup{\mathrm P}\;=\;\overset\rightharpoonup{{\mathrm P}_{\mathrm{res}}}$

Der Stützvektor P ist hier der zu untersuchende Ergebnispunkt Pres. Der Normalenvektor ist der Richtungsvektor der Geraden, da so die Ebene orthogonal zur Geraden ist. Bevor der Abstand berechnet werden kann, muss noch der Faktor s der Geraden ermittelt werden, an der die Ebene die Gerade schneidet. Dazu wird der Ortsvektor X in der Ebenengleichung durch die Geradengleichung ersetzt.

$(1)\;\mathrm{in}\;(2):\;0\;=\;((\overset\rightharpoonup{\mathrm A}\;+\;\mathrm s\;\cdot\;\overset\rightharpoonup{\mathrm v})\;-\;\overset\rightharpoonup{\mathrm P})\;\cdot\;\overset\rightharpoonup{\mathrm n}\;(3)$

Nach s umgestellt und mit $\overset\rightharpoonup{\mathrm n}\;=\;\overset\rightharpoonup{\mathrm v}$ ergibt sich folgende Gleichung.

$\mathrm s\;=\;\frac{(\overset\rightharpoonup{\mathrm P}\;-\;\overset\rightharpoonup{\mathrm A})\;\cdot\;\overset\rightharpoonup{\mathrm v}}{(\overset\rightharpoonup{\mathrm v}\;\cdot\;\overset\rightharpoonup{\mathrm v})}\;(4)$

Damit lässt sich nun über Gleichung 1 der Schnittpunkt S ermitteln.

$\overset\rightharpoonup{\mathrm S}\;=\;\overset\rightharpoonup{\mathrm A}\;+\;\mathrm s\;\cdot\;\overset\rightharpoonup{\mathrm v}\;(5)$

Der Abstand d zwischen S und Pres wird mit Hilfe des vektoriellen Betrags der Differenz der beiden bestimmt.

$\mathrm d\;=\;\left|\overset\rightharpoonup{{\mathrm P}_{\mathrm{res}}}\;-\;\overset\rightharpoonup{\mathrm S}\right|\;(6)$

Bild 01 zeigt die schematische Darstellung aller aufgeführten Elemente. Die blaue Fläche ist die zu untersuchende Fläche und die rote Fläche stellt die Schnittebene dar, welche mit Punkt Pres und Richtungsvektor $\overset\rightharpoonup{\mathrm v}$ aufgestellt wurde. Der Faktor s ist im Bild gerade 0,5, sodass der Schnittpunkt von Ebene und Gerade genau in der Mitte der Linie liegt.

Bild 01 - Schematische Darstellung der Komponenten zur Abstandsberechnung

Umsetzung der Abstandsberechnung in einem Programm

Nachdem die Formeln zur Verfügung stehen, kann das entsprechende Programm erstellt werden. Für die Umsetzung wird EXCEL VBA verwendet. In Bild 02 ist die Nummerierung der Elemente zu sehen.

Bild 02 - Modell für Beispielrechnung

Zuerst muss die Verbindung zu RFEM aufgebaut werden. Danach wird das Interface zu den Modelldaten geholt. Da diese Vorgehensweise bereits in diversen anderen Beiträgen beschrieben wurde (siehe Links), wird hier nicht näher darauf eingegangen. Nachfolgend der Quellcode für den Anfang des Programms.

Sub selection_test2()
    
    Dim line_no As Integer
    Dim surface_no As Integer
    Dim loadcase_no As Integer
    Dim d_tol As Double
    line_no = 11
    surface_no = 1
    loadcase_no = 1
    d_tol = 0.001
    
    '   get interface from the opened model and lock the licence/program
    Dim iModel As RFEM5.IModel2
    Set iModel = GetObject(, "RFEM5.Model")
    iModel.GetApplication.LockLicense
    
On Error GoTo e
    
    Dim iModelData As RFEM5.IModelData2
    Set iModelData = iModel.GetModelData

Bevor das Programm startet, werden zunächst die variablen gegebenen Parameter definiert. Dazu gehören die Liniennummer line_no der Linie, an der nach Ergebnissen gesucht werden soll, und natürlich die Flächennummer surface_no der Fläche, in der die Linie liegt. Des Weiteren wird noch die Nummer des Lastfalls loadcase_no benötigt, zu dem die Ergebnisse gehören. Da es sich um eine numerische Berechnung mit begrenzter Genauigkeit handelt, wird eine Toleranz d_tol benötigt, welche den maximalen Abstand zwischen Linie und Knoten vorgibt. Im Beispiel wurde eine Toleranz von einem Millimeter verwendet.

Da das Interface für die Modelldaten (IModelData) nun zur Verfügung steht, kann zuerst die Linie gesucht werden und damit auch deren Anfangs- und Endpunkt.

   '   get line
    Dim ILin As RFEM5.ILine
    Set ILin = iModelData.GetLine(line_no, AtNo)
    Dim lin As RFEM5.RfLine
    lin = ILin.GetData
   
    
    '   get nodes from line
    Dim n(0 To 1) As RFEM5.Node
    
    Dim ints() As Integer
    ints = strToIntArr(lin.NodeList)
    
    Dim iNd As RFEM5.INode
    Set iNd = iModelData.GetNode(ints(0), AtNo)
    n(0) = iNd.GetData
    Set iNd = iModelData.GetNode(ints(UBound(ints, 1)), AtNo)
    n(1) = iNd.GetData
    
    Set iNd = Nothing

Sowohl die Knoten als auch die Linie werden einzeln direkt über deren Interface (INode beziehungsweise ILine) geholt. Die Extraktion der Knotennummern aus der Zeichenkette (RfLine.NodeList) erfolgt über die Funktion strToIntArr, welche in einem anderen Beitrag beschrieben wurde (siehe Links). Sie wandelt die Zeichenkette in ein Integer-Feld um.

Mit den jetzt gegebenen Punkten der Linie $\overset\rightharpoonup{{\mathrm N}_0}$ (Anfangspunkt) und $\overset\rightharpoonup{{\mathrm N}_1}$ (Endpunkt) lassen sich die ersten Parameter der Gleichung aufstellen.

    Dim v As RFEM5.Point3D
    v.X = N(1).X - N(0).X
    v.Y = N(1).Y - N(0).Y
    v.Z = N(1).Z - N(0).Z
    
    Dim A As RFEM5.Point3D
    A.X = N(0).X
    A.Y = N(0).Y
    A.Z = N(0).Z
    
    Dim v2 As Double
    v2 = v.X ^ 2 + v.Y ^ 2 + v.Z ^ 2
    
    Dim P_res As RFEM5.Point3D
    Dim s As Double
    Dim d As Double

Es werden der Richtungsvektor $\overset\rightharpoonup{\mathrm v}$ (v), der Stützvektor $\overset\rightharpoonup{\mathrm A}$ (A) und das Skalaprodukt des Richtungsvektors $\overset\rightharpoonup{\mathrm v}\cdot\;\overset\rightharpoonup{\mathrm v}$ (v2) berechnet beziehungsweise vorbereitet. Des Weiteren werden auch die Variablen Pres (P_res) für den Punkt des Ergebnisses und s für den Faktor aus der Geradengleichung (1) definiert.

Berechnung des Abstandes in einer Schleife

In diesem Beispiel wurde die Verarbeitung der Ergebnisse auf Basis der FE-Knoten gewählt. Die Überprüfung des Abstandes erfolgt in einer Schleife über das Feld dieser Ergebnisse. Zuvor müssen diese Ergebnisse über das Interface ICalculation2 und dann IResults geholt werden. Innerhalb der Schleife wird zunächst der Punkt Pres mit den Koordinaten des Ergebniswertes beschrieben (dient der Übersichtlichkeit). Danach kann die direkte Berechnung der Gleichung (4) erfolgen. Nachdem s berechnet wurde, kann überprüft werden, ob der Wert kleiner Null oder größer Eins ist, da diese Werte außerhalb beziehungsweise vor und nach der Geraden liegen. Falls ein Wert innerhalb des Bereichs liegt, wird der Abstand mit Gleichung (6) berechnet.

    '       get results in fe-nodes
    Dim iCalc As ICalculation2
    Set iCalc = iModel.GetCalculation
    
    Dim iRes As RFEM5.IResults
    Set iRes = iCalc.GetResultsInFeNodes(LoadCaseType, loadcase_no)
    
    Dim surfBaStr() As RFEM5.SurfaceBasicStresses
    surfBaStr = iRes.GetSurfaceBasicStresses(surface_no, AtNo)
    
    '       loop through stresses and calculate distance to line
    Dim i As Integer
    For i = 0 To UBound(surfBaStr, 1)
        P_res.X = surfBaStr(i).Coordinates.X
        P_res.Y = surfBaStr(i).Coordinates.Y
        P_res.Z = surfBaStr(i).Coordinates.Z
        '   calculate factor for line equation of intersection
        s = ((P_res.X-A.X)*v.X + (P_res.Y-A.Y)*v.Y + (P_res.Z-A.Z)*v.Z) / v2
        
        If s <= 1 + d_tol And s >= 0 - d_tol Then
            '   calculate distance of intersection point and fe-node
            d = ((P_res.X-(A.X+s*v.X))^2
                 +(P_res.Y-(A.Y+s*v.Y))^2
                 +(P_res.Z-(A.Z+s*v.Z))^2)^0.5
            
            If (d < d_tol) Then
                ' here you can process the found result point
            End If
        End If
        
    Next i

Sowohl die Überprüfung des Faktors s als auch die des Abstandes d wird mit der Toleranz beaufschlagt, damit etwaige kleine Ungenauigkeiten nicht zum Ausschluss eines Ergebnisses führen.

Ergebnisse des Programms

Die vom Programm gefundenen Werte sind in der Tabelle dargestellt, dabei wurden die Werte auf zwei Stellen nach dem Komma gerundet.

σy+ [N/mm²]Faktor s [-]
21,900,0
17,280,1
12,790,2
8,430,3
4,170,4
-0,040,5
-4,250,6
-8,510,7
-12,870,8
-17,360,9
-21,981,0

Dem gegenüber stehen die Werte aus dem Ergebnisverlauf an der entsprechenden Linie, welche in Bild 03 dargestellt werden.

Bild 03 - Ergebnisverlauf an der untersuchten Linie

Es ist deutlich zu erkennen, dass es sich um die gleichen Werte handelt und es zu einer hundertprozentigen Übereinstimmung kommt beziehungsweise alle Werte an der Linie gefunden wurden.

Zusammenfassung

Mit Hilfe der Vektorrechnung wurde ein Programm erstellt, welches in der Lage ist, Knoten entlang einer Linie zu finden. Mit diesem Algorithmus können neben Ergebnissen natürlich auch alle anderen geometrischen Elemente gesucht werden. Dies ist vor allem hilfreich, da die visuelle Selektion natürlich über die COM-Schnittstelle nicht möglich ist, so aber über eine Funktion auf anderem Weg möglich wird. Gerade für Programme, welche komplett im Hintergrund laufen, kann damit eine automatische Ergebnisauswertung erfolgen.

Schlüsselwörter

COM-Schnittstelle Ergebnisse einer Fläche auslesen Ergebnisse entlang einer Linie auslesen Knoten entlang einer Linie finden automatische Ergebnisauswertung Selektion über COM-Schnittstelle

Downloads

Links

Kontakt

Kontakt zu Dlubal

Haben Sie Fragen oder brauchen Sie einen Rat? Kontaktieren Sie uns über unseren kostenlosen E-Mail-, Chat- bzw. Forum-Support oder nutzen Sie die häufig gestellten Fragen (FAQs) rund um die Uhr.

+49 9673 9203 0

info@dlubal.com

RFEM Hauptprogramm
RFEM 5.xx

Basisprogramm

Das FEM-Programm RFEM ermöglicht die schnelle und einfache Modellierung, Berechnung und Bemessung von Tragkonstruktionen mit Stab-, Platten-, Scheiben-, Faltwerk-, Schalen- und Volumen-Elementen aus verschiedenen Materialien.

Erstlizenzpreis
3.540,00 USD
RFEM Sonstige
RF-COM 5.xx

Zusatzmodul

Programmierbare COM-Schnittstelle

Erstlizenzpreis
580,00 USD
RSTAB Hauptprogramm
RSTAB 8.xx

Basisprogramm

Das 3D-Statik-Programm RSTAB eignet sich für die Berechnung von Stabwerken aus Stahl, Beton, Holz, Aluminium oder anderen Materialien. Mit RSTAB definieren Sie einfach und schnell das Tragwerksmodell und berechnen dann die Schnittgrößen, Verformungen und Lagerreaktionen.

Erstlizenzpreis
2.550,00 USD
RSTAB Sonstige
RS-COM 8.xx

Zusatzmodul

Programmierbare COM-Schnittstelle

Erstlizenzpreis
580,00 USD